model
    {
    for(i in 1:s_total){
    y_s[i] ~ dnorm(nu + mu[y_s_region[i]] + w[s_id[i]], inv_tausq[y_s_region[i]])
    y_s_pred[i] ~ dnorm(nu + mu[y_s_region[i]] + w[s_id[i]], inv_tausq[y_s_region[i]])
    y_s_ll[i] <- logdensity.norm(y_s[i],nu + mu[y_s_region[i]] + w[s_id[i]], inv_tausq[y_s_region[i]])
    }
    
    nu ~ dnorm(0, 0.001)
    inv_deltasq ~ dgamma(2, 0.1)
    deltasq <- 1/inv_deltasq
    for(j in 1:N){
    mu[j] ~ dnorm(0,inv_deltasq)
    inv_tausq[j] ~ dgamma(2, 0.0006)
    inv_sigmasq[j] ~ dgamma(2, 0.001)
    phi[j] ~ dunif(phi_a, phi_b)
    }
    
    for(i in 1:N){
	for(j in 1:region_total[i]){
	for(k in 1:region_total[i]){
	bigsigma[i,j,k]	<- exp(-phi[i]*d[region_cum_total[i]+j, region_cum_total[i]+k])
	}
	}
	bigsigma_inv[i,1: region_total[i],1: region_total[i]] <- inverse(bigsigma[i,1: region_total[i],1: region_total[i]])
    w[(region_cum_total[i] + 1): region_cum_total[i + 1]] ~ dmnorm(rep(0, region_total[i]), 
    inv_sigmasq[i]*bigsigma_inv[i,1: region_total[i],1: region_total[i]])
    }

    for(i in 1:ns_total){
    Y_ns[i] ~ dnorm(nu + mu[Y_ns_region[i]] + w[ns_id[i]], inv_tausq[Y_ns_region[i]])
    }
    
    grand_mean = (y_s_total + sum(Y_ns))/pop_total
    for(k in 1:N){
      mu_pred[k] = sum(Y_ns[(site_ends[k]+1):site_ends[k+1]]) + sum_samp[k]
    }
    }